如何更有效地打开文本文件应该是一个值得研究的课题，假设F盘下有一个名为d.txt的文本文件，若需要尝试这些例子请作相应的改动。
　　
　　方法一:
　　用定长的String变量获取文本内容。由于定长String变量支持的下界为65400,所以在打开超过32K字节的文件时超出部分的字节将无法获取:
　　Private Sub Command1_Cliack()
　　Dim sA As String * 65400 '声明定长String变量
　　Open "F:\d.txt" For Binary As #1 '用二进制打开文件
　　Get #1, , sA '用Get语句从文件中获取字节
　　Text1 = sA '显示打开的文件
　　Close #1 '关闭文件
　　End Sub
　　
　　方法二:
　　先声明一字符串变量，然后用空格填充字符串，使变量大小与文件大小一致，再通过Get语句将文件全部数据存储到变量中，从而达到获取整个文件字节数的目的。此法可以打开大于32K的文件，但应该注意的是，装载文件的容器必须能装载大于32K的文件，下例用RichTextBox控件显示打开的文件：
　　Private Sub Command1_Click()
　　Dim sA As String
　　Open "f:\d.txt" For Binary As #1
　　sA = Space(LOF(1)) '用空格填充sA变量
　　Get #1, , sA '用Get语句获取文件全部内容
　　RichTextBox1.Text = sA
　　Close #1
　　End Sub
　　
　　方法三：
　　用StrConv函数将文件的控制字符串数据和Unicode码之间进行转换，从而达到打开文件的目的。可打开任意大小文件。此法笔者曾有一篇文章谈及，这里再给一个简单例子：
　　Private Sub Command1_Click()
　　Open "f:\d.txt" For Input As #1
　　RichTextBox1.Text = StrConv(InputB$(LOF(1), 1), vbUnicode)
　　Close #1
　　End Sub
　　
　　方法四：
　　用Shell语句直接调出Windows的记事本，给个文件名即可轻而易举地打开文本文件。此法适合于打开程序的Readme文件(注意：在可执行文件和要打开的文本文件之间要有空格)：
　　Shell "NotePad.EXE f:\d.txt",vbNormalFucus
　　
　　方法五：
　　用RichTextBox控件自身的LoadFile属性打开文件：
　　RichTextBox1.LoadFile "f:\d.txt", rtfText

Tags: vb

1、添加引用microsoft    scripting    runtime   
   方法：选择菜单“工程”-->“引用”-->选择“microsoft    scripting    runtime”   
    
   2、使用方法   
   Option    Explicit   
    
   Private    Sub    Form_Load()   
   Dim    FileSys    As    New    FileSystemObject   
   Dim    FolderObj    As    Folder   
   Set    FileSys    =    CreateObject("scripting.filesystemobject")   
   FileSys.CopyFile    "c:\ss.txt",    "d:\mm.txt",    True    '拷贝文件   
   FileSys.CopyFolder    "c:\1",    "d:\2",    True            '拷贝文件夹

Tags: vb

利用 WinSock 控件可以与远程计算机建立连接，并通过用户数据文报协议 (UDP)或者传输控制协议 (TCP)进行数据交换。这两种协议都可以用来创建客户与服务器应用程序。与 Timer 控件类似，WinSock 控件在运行时是不可见的。

可能的用途
创建收集用户信息的客户端应用程序，并将收集的信息发送到某中央服务器。


创建一个服务器应用程序，作为多个用户的数据的汇入点。


创建“聊天”应用程序。
选择通讯协议
在使用 WinSock 控件时，首先需要考虑使用什么协议。可以使用的协议包括 TCP 和 UDP。两种协议之间的重要区别在于它们的连接状态：

TCP 协议控件是基于连接的协议，可以将它同电话系统相比。在开始数据传输之前，用户必须先建立连接。


UDP 协议是一种无连接协议，两台计算机之间的传输类似于传递邮件：消息从一台计算机发送到另一台计算机，但是两者之间没有明确的连接。另外，单次传输的最大数据量取决于具体的网络。
到底选择哪一种协议通常是由需要创建的应用程序决定的。下面的几个问题将有助于选择适宜的协议：

在收发数据的时候，应用程序是否需要得到客户端或者服务器的确认信息？如果需要，使用 TCP 协议，在收发数据之前先建立明确的连接。


数据量是否特别大（例如图象与声音文件）？在连接建立之后，TCP 协议将维护连接并确保数据的完整性。不过，这种连接需要更多的计算资源，因而是比较“昂贵”的。


数据发送是间歇的，还是在一个会话内？例如，如果应用程序在某个任务完成的时候需要通知某个计算机，UDP 协议是更适宜的。UDP 协议适合发送少量的数据。
协议的设置
在设计时，可以按如下方式设置应用程序使用的协议：在“属性”窗口中单击“协议”，然后选择 sckTCPProtocol 或者 sckUDPProtocol。也可以使用程序代码来设置 Protocol 属性，如下所示：

Winsock1.Protocol = sckTCPProtocol

确定计算机的名称
在与远程计算机相连接的时候，需要知道它的 IP 地址或者它的“好听的名字”。IP 地址是一串数字，每三个数字为一组，中间用点隔开（形如 xxx.xxx.xxx.xxx）。通常，最易记住的是计算机的“好听的名字”。

要确定计算机的名字，请按照以下步骤执行：

在计算机的“任务栏”上，单击“启动”。


在“设置”项中，单击“控制面板”。


双击“网络”图标。


单击“标识”选项卡。


在“计算机名称”框中可以找到计算机的名称。
上面找到的计算机名称可以作为 RemoteHost 属性的值。

TCP 连接初步
如果应用程序要使用 TCP 协议，那么首先必须决定应用程序是服务器还是客户端。如果要创建一个服务器端，那么应用程序需要“监听”指定的端口。当客户端提出连接请求时，服务器端能够接受请求并建立连接。在连接建立之后，客户端与服务器端可以自由地互相通讯。

下列步骤创建一个非常简单的服务器：

要创建一个 TCP 服务器，请按照以下步骤执行：

创建新的 Standard EXE 工程。


将缺省窗体的名称改为 frmServer。


将窗体的标题改为“TCP 服务器”。


在窗体中放入一个 Winsock 控件，并将它的名字改为 tcpServer。


在窗体上添加两个 TextBox 控件。将第一个命名为 txtSendData，第二个为 txtOutput。


为窗体添加如下的代码。
Private Sub Form_Load()
'将 LocalPort 属性设置为一个整数。
'然后调用 Listen 方法。
tcpServer.LocalPort = 1001
tcpServer.Listen
frmClient.Show '显示客户端的窗体。
End Sub

Private Sub tcpServer_ConnectionRequest _
(ByVal requestID As Long)
'检查控件的 State 属性是否为关闭的。
'如果不是，
'在接受新的连接之前先关闭此连接。
If tcpServer.State <> sckClosed Then _
tcpServer.Close
'接受具有 requestID 参数的
'连接。
tcpServer.Accept requestID
End Sub

Private Sub txtSendData_Change()
'名为 txtSendData 的 TextBox 控件中
'包含了要发送的数据。当用户往文本框中
'键入数据时，使用 SendData 方法
'发送输入的字符串。
tcpServer.SendData txtSendData.Text
End Sub

Private Sub tcpServer_DataArrival _
(ByVal bytesTotal As Long)
'为进入的数据声明一个变量。
'调用 GetData 方法，并将数据赋予名为 txtOutput
'的 TextBox 的 Text 属性。
Dim strData As String
tcpServer.GetData strData
txtOutput.Text = strData
End Sub

上面的步骤创建了一个简单的服务器应用程序。为了使它能够工作，还必须为它创建一个客户端的应用程序。

要创建 TCP 客户端，请按照以下步骤执行：

在工程中添加一个新的窗体，将其命名为 frmClient。


将窗体的标题改为“TCP Client”。


在窗体中添加一个 Winsock 控件，并将其命名为 tcpClient。


在 frmClient 中添加两个 TextBox 控件。将第一个命名为 txtSend，第二个为 txtOutput。


在窗体上放一个 CommandButton 控件，并将其命名为 cmdConnect。


将 CommandButton 控件的标题改为 Connect。


在窗体中添加如下的代码。
重点 必须将 RemoteHost 属性值修改为您的计算机的名字。

Private Sub Form_Load()
'Winsock 控件的名字为 tcpClient。
'注意：要指定远程主机，可以使用
' IP 地址（例如："121.111.1.1"），也可以使用
'计算机的“好听的名字”如下所示。
tcpClient.RemoteHost = "RemoteComputerName"
tcpClient.RemotePort = 1001
End Sub

Private Sub cmdConnect_Click()
'调用 Connect 方法，初始化连接。
tcpClient.Connect
End Sub

Private Sub txtSendData_Change()
tcpClient.SendData txtSend.Text
End Sub

Private Sub tcpClient_DataArrival _
(ByVal bytesTotal As Long)
Dim strData As String
tcpClient.GetData strData
txtOutput.Text = strData
End Sub

上面的代码创建了一个简单的客户/服务器模式的应用程序。我们可以将两者都运行起来：运行工程，然后单击“连接”。在两个窗体之一的 txtSendData 文本框中键入文本，可以看到同样的文字将出现在另一个窗体的 txtOutput 文本框中。

接受多个连接请求
上面设计的基本服务器只能接受一个连接请求。通过创建控件数组，使用一个控件也可以同时接受多个连接请求。利用这种方法，不需要关闭连接，而只需创建新的控件实例（通过设置其索引属性），然后在新的实例上调用 Accept 方法。

下面的代码假定名为 sckServer 的窗体上有一个 Winsock 控件，它的 Index 属性被设置为 0；因此控件是控件数组的一部分。在声明部分，声明了一个模块级的变量 intMax。在窗体的 Load 事件中，intMax 被设置为 0，数组中第一个控件的 LocalPort 属性被设置为 1001。然后调用控件的 Listen 方法，使之成为“监听”控件。在连接请求到达时，代码将检测 Index 是否为 0（“监听”控件的值）。如果为 0，监听控件将增加 intMax 的值，并使用该号码来创建新的控件实例。然后，使用新的控件实例接受连接请求。

Private intMax As Long

Private Sub Form_Load()
intMax = 0
sckServer(0).LocalPort = 1001
sckServer(0).Listen
End Sub

Private Sub sckServer_ConnectionRequest _
(Index As Integer, ByVal requestID As Long)
If Index = 0 Then
intMax = intMax + 1
Load sckServer(intMax)
sckServer(intMax).LocalPort = 0
sckServer(intMax).Accept requestID
Load txtData(intMax)
End If
End Sub

UDP 初步
创建 UDP 应用程序比创建 TCP 应用程序还要简单，因为 UDP 协议不需要显式的连接。在上面的 TCP 应用程序中，一个 Winsock 控件必须显式地进行“监听”，另一个必须使用 Connect 方法初始化连接。

UDP 协议不需要显式的连接。要在两个控件中间发送数据，需要完成以下的三步（在连接的双方）：

将 RemoteHost 属性设置为另一台计算机的名称。


将 RemotePort 属性设置为第二个控件的 LocalPort 属性。


调用 Bind 方法，指定使用的 LocalPort。（下面将详细地讨论该方法。）
因为两台计算机的地位可以看成“平等的”，这种应用程序也被称为点到点的。为了具体说明这个问题，下面将创建一个“聊天”应用程序，两个人可以通过它进行实时的交谈。

要创建一个 UDP 伙伴，请按照以下步骤执行：

创建一个新的 Standard EXE 工程。


将缺省的窗体的名称修改为 frmPeerA。


将窗体的标题修改为“Peer A”。


在窗体中放入一个 Winsock 控件，并将其命名为 udpPeerA。


在“属性”页上，单击“协议”并将协议修改为 UDPProtocol。


在窗体中添加两个 TextBox 控件。将第一个命名为 txtSend，第二个命名为 txtOutput。


为窗体增加如下的代码。
Private Sub Form_Load()
'控件的名字为 udpPeerA
With udpPeerA
'重点:必须将 RemoteHost 的值
'修改为计算机的名字。
.RemoteHost= "PeerB"
.RemotePort = 1001 '连接的端口号。
.Bind 1002 '绑定到本地的端口。
End With
frmPeerB.Show '显示第二个窗体。
End Sub

Private Sub txtSend_Change()
'在键入文本时，立即将其发送出去。
udpPeerA.SendData txtSend.Text
End Sub

Private Sub udpPeerA_DataArrival _
(ByVal bytesTotal As Long)
Dim strData As String
udpPeerA.GetData strData
txtOutput.Text = strData
End Sub

要创建第二个 UDP 伙伴，请按照以下步骤执行：

在工程中添加一个标准窗体。


将窗体的名字修改为 frmPeerB。


将窗体的标题修改为“Peer B”。


在窗体中放入一个 Winsock 控件，并将其命名为 udpPeerB。


在“属性”页上，单击“协议”并将协议修改为“UDPProtocol”。


在窗体上添加两个 TextBox 控件。将第一个命名为 txtSend，第二个命名为 txtOutput。


在窗体中添加如下的代码。
Private Sub Form_Load()
'控件的名字为 udpPeerB。
With udpPeerB
'重点:必须将 RemoteHost 的值改为
'计算机的名字。
.RemoteHost= "PeerA"
.RemotePort = 1002 '要连接的端口。
.Bind 1001 '绑定到本地的端口上。
End With
End Sub

Private Sub txtSend_Change()
'在键入后立即发送文本。
udpPeerB.SendData txtSend.Text
End Sub

Private Sub udpPeerB_DataArrival _
(ByVal bytesTotal As Long)
Dim strData As String
udpPeerB.GetData strData
txtOutput.Text = strData
End Sub

如果要试用上面的例子，按 F5 键运行工程，然后在两个窗体的 txtSend TextBox 中分别键入一些文本。键入的文字将出现在另一个窗体的 txtOutput TextBox 中。

关于 Bind 方法
在上面的代码中，在创建 UDP 应用程序时调用了 Bind 方法，这是必须的。Bind 方法的作用是为控件“保留”一个本地端口。例如，如果将控件绑定到 1001 号端口，那么其它应用程序将不能使用该端口进行“监听”。该方法阻止其它应用程序使用同样的端口。

Bind 方法的第二个参数是任选的。如果计算机上存在多个网络适配器，可以用 LocalIP 参数来指定使用哪一个适配器。如果忽略该参数，控件使用的将是计算机上“控制面板”设置中“网络”控制面板对话框中列出的第一个适配器。

在使用 UDP 协议的时候，可以任意地改变 RemoteHost 和 RemotePort 属性，同时始终保持绑定在同一个 LocalPort 上。TCP 协议与此不同，在改变 RemoteHost 和 RemotePort 属性之前，必须先关闭连接。

Tags: vb

StatusBar 控件由 Panel 对象组成，每一个 Panel 对象能包含文本和/或图片。控制个别面板的外观属性包括 Width、Alignment（文本和图片的）和 Bevel。此外，能使用 Style 属性七个值中的一个自动地显示公共数据，诸如日期、时间和键盘状态等。

在设计时，在 StatusBar 控件的属性页的“窗格”选项卡中设置的值能建立面板并定制它们的外观。在运行时，能重新配置 Panel 对象以反映不同的功能，这些功能取决于应用程序的状态。关于 Panel 对象的属性、事件和方法的详细信息，请参阅“Panel 对象和 Panels 集合”的主题。

StatusBar 控件代表性地显示有关在窗体上查看的对象、对象组件的信息或关系到对象操作的上下文的信息。StatusBar 控件与其它控件如 Toolbar 控件一起，提供建立界面的工具，该界面既经济又含有丰富的信息。

发行注意 StatusBar 控件是自定义控件组的一部分，该控件可在 MSCOMCTL.OCX 文件中找到。为了在应用程序中使用 StatusBar 控件，必须将 MSCOMCTL.OCX 文件添加到工程中。当发布应用程序时，请在用户的 Microsoft Windows SYSTEM 目录下安装 MSCOMCTL.OCX 文件。如何将自定义的控件添加到工程中的详细信息，请参阅《程序员指南》。


StatusBar 控件常数


StatusBar 样式常数

常数 值 描述
sbrNormal 0 正常。StatusBar 被分成面板。
sbrSimple 1 简化。StatusBar 只有一个大面板和简化文本。


面板对齐常数

常数 值 描述
sbrLeft 0 文本靠左。
sbrCenter 1 文本居中。
sbrRight 2 文本靠右。


面板自动调整大小常数

常数 值 描述
sbrNoAutoSize 0 非自动调整大小。
sbrSpring 1 在面板中划分附加空间。
sbrContents 2 符合于目录。


面板斜面常数

常数 值 描述
sbrNoBevel 0 无斜面。
sbrInset 1 斜面插入。
sbrRaised 2 斜面凸起。


面板样式常数

常数 值 描述
sbrText 0 显示文本和/或位图。
sbrCaps 1 显示 Caps Lock 状态。
sbrNum 2 显示 Number Lock 状态。
sbrIns 3 显示 Insert 键状态。
sbrScrl 4 显示 Scroll Lock 状态。
sbrTime 5 以 System 格式显示时间。
sbrDate 6 以 System 格式显示日期。
sbrKana 7 Kana。当激活滚动锁定时，显示黑体字母 KANA，反之当停用滚动锁定时，则显示暗淡的字母 KANA。

Tags: vb

学会数据库是很实用D~~记录一些常用的sql语句...有入门有提高有见都没见过的...好全...收藏下...
其实一般用的就是查询,插入,删除等语句而已....但学学存储过程是好事...以后数据方面的东西就不用在程序里搞喽..而且程序与数据库只要一个来回通讯就可以搞定所有数据的操作....

一、基础

1、说明：创建数据库
Create DATABASE database-name
2、说明：删除数据库
drop database dbname
3、说明：备份sql server
--- 创建 备份数据的 device
USE master
EXEC sp_addumpdevice 'disk', 'testBack', 'c:\mssql7backup\MyNwind_1.dat'
--- 开始 备份
BACKUP DATABASE pubs TO testBack
4、说明：创建新表
create table tabname(col1 type1 [not null] [primary key],col2 type2 [not null],..)
根据已有的表创建新表：
A：create table tab_new like tab_old (使用旧表创建新表)
B：create table tab_new as select col1,col2… from tab_old definition only
5、说明：删除新表
drop table tabname
6、说明：增加一个列
Alter table tabname add column col type
注：列增加后将不能删除。DB2中列加上后数据类型也不能改变，唯一能改变的是增加varchar类型的长度。
7、说明：添加主键： Alter table tabname add primary key(col)
说明：删除主键： Alter table tabname drop primary key(col)
8、说明：创建索引：create [unique] index idxname on tabname(col….)
删除索引：drop index idxname
注：索引是不可更改的，想更改必须删除重新建。
9、说明：创建视图：create view viewname as select statement
删除视图：drop view viewname
10、说明：几个简单的基本的sql语句
选择：select * from table1 where 范围
插入：insert into table1(field1,field2) values(value1,value2)
删除：delete from table1 where 范围
更新：update table1 set field1=value1 where 范围
查找：select * from table1 where field1 like ’%value1%’ ---like的语法很精妙，查资料!
排序：select * from table1 order by field1,field2 [desc]
总数：select count as totalcount from table1
求和：select sum(field1) as sumvalue from table1
平均：select avg(field1) as avgvalue from table1
最大：select max(field1) as maxvalue from table1
最小：select min(field1) as minvalue from table1
11、说明：几个高级查询运算词
A： UNION 运算符
UNION 运算符通过组合其他两个结果表（例如 TABLE1 和 TABLE2）并消去表中任何重复行而派生出一个结果表。当 ALL 随 UNION 一起使用时（即 UNION ALL），不消除重复行。两种情况下，派生表的每一行不是来自 TABLE1 就是来自 TABLE2。
B： EXCEPT 运算符
EXCEPT 运算符通过包括所有在 TABLE1 中但不在 TABLE2 中的行并消除所有重复行而派生出一个结果表。当 ALL 随 EXCEPT 一起使用时 (EXCEPT ALL)，不消除重复行。
C： INTERSECT 运算符
INTERSECT 运算符通过只包括 TABLE1 和 TABLE2 中都有的行并消除所有重复行而派生出一个结果表。当 ALL 随 INTERSECT 一起使用时 (INTERSECT ALL)，不消除重复行。
注：使用运算词的几个查询结果行必须是一致的。
12、说明：使用外连接
A、left outer join：
左外连接（左连接）：结果集几包括连接表的匹配行，也包括左连接表的所有行。
SQL: select a.a, a.b, a.c, b.c, b.d, b.f from a LEFT OUT JOIN b ON a.a = b.c
B：right outer join:
右外连接(右连接)：结果集既包括连接表的匹配连接行，也包括右连接表的所有行。
C：full outer join：
全外连接：不仅包括符号连接表的匹配行，还包括两个连接表中的所有记录。

二、提升

1、说明：复制表(只复制结构,源表名：a 新表名：b) (Access可用)
法一：select * into b from a where 1<>1
法二：select top 0 * into b from a
2、说明：拷贝表(拷贝数据,源表名：a 目标表名：b) (Access可用)
insert into b(a, b, c) select d,e,f from b;

3、说明：跨数据库之间表的拷贝(具体数据使用绝对路径) (Access可用)
insert into b(a, b, c) select d,e,f from b in ‘具体数据库’ where 条件
例子：..from b in '"&Server.MapPath("."&"\data.mdb" &"' where..

4、说明：子查询(表名1：a 表名2：b)
select a,b,c from a where a IN (select d from b   或者: select a,b,c from a where a IN (1,2,3)

5、说明：显示文章、提交人和最后回复时间
select a.title,a.username,b.adddate from table a,(select max(adddate) adddate from table where table.title=a.title) b

6、说明：外连接查询(表名1：a 表名2：b)
select a.a, a.b, a.c, b.c, b.d, b.f from a LEFT OUT JOIN b ON a.a = b.c

7、说明：在线视图查询(表名1：a
select * from (Select a,b,c FROM a) T where t.a > 1;

8、说明：between的用法,between限制查询数据范围时包括了边界值,not between不包括
select * from table1 where time between time1 and time2
select a,b,c, from table1 where a not between 数值1 and 数值2

9、说明：in 的使用方法
select * from table1 where a [not] in (‘值1’,’值2’,’值4’,’值6’)

10、说明：两张关联表，删除主表中已经在副表中没有的信息
delete from table1 where not exists ( select * from table2 where table1.field1=table2.field1

11、说明：四表联查问题：
select * from a left inner join b on a.a=b.b right inner join c on a.a=c.c inner join d on a.a=d.d where .....

12、说明：日程安排提前五分钟提醒
SQL: select * from 日程安排 where datediff('minute',f开始时间,getdate())>5

13、说明：一条sql 语句搞定数据库分页
select top 10 b.* from (select top 20 主键字段,排序字段 from 表名 order by 排序字段 desc) a,表名 b where b.主键字段 = a.主键字段 order by a.排序字段

14、说明：前10条记录
select top 10 * form table1 where 范围

15、说明：选择在每一组b值相同的数据中对应的a最大的记录的所有信息(类似这样的用法可以用于论坛每月排行榜,每月热销产品分析,按科目成绩排名,等等.)
select a,b,c from tablename ta where a=(select max(a) from tablename tb where tb.b=ta.b)

16、说明：包括所有在 TableA 中但不在 TableB和TableC 中的行并消除所有重复行而派生出一个结果表
(select a from tableA   except (select a from tableB) except (select a from tableC)

17、说明：随机取出10条数据
select top 10 * from tablename order by newid()

18、说明：随机选择记录
select newid()

19、说明：删除重复记录
Delete from tablename where id not in (select max(id) from tablename group by col1,col2,...)

20、说明：列出数据库里所有的表名
select name from sysobjects where type='U'

21、说明：列出表里的所有的
select name from syscolumns where id=object_id('TableName')

22、说明：列示type、vender、pcs字段，以type字段排列，case可以方便地实现多重选择，类似select 中的case。
select type,sum(case vender when 'A' then pcs else 0 end),sum(case vender when 'C' then pcs else 0 end),sum(case vender when 'B' then pcs else 0 end) FROM tablename group by type
显示结果：
type vender pcs
电脑 A 1
电脑 A 1
光盘 B 2
光盘 A 2
手机 B 3
手机 C 3

23、说明：初始化表table1

TRUNCATE TABLE table1

24、说明：选择从10到15的记录
select top 5 * from (select top 15 * from table order by id asc) table_别名 order by id desc

三、技巧

1、1=1，1=2的使用，在SQL语句组合时用的较多

“where 1=1” 是表示选择全部   “where 1=2”全部不选，
如：
if @strWhere !='
begin
set @strSQL = 'select count(*) as Total from [' + @tblName + '] where ' + @strWhere
end
else
begin
set @strSQL = 'select count(*) as Total from [' + @tblName + ']'
end

我们可以直接写成
set @strSQL = 'select count(*) as Total from [' + @tblName + '] where 1=1 安定 '+ @strWhere

2、收缩数据库
--重建索引
DBCC REINDEX
DBCC INDEXDEFRAG
--收缩数据和日志
DBCC SHRINKDB
DBCC SHRINKFILE

3、压缩数据库
dbcc shrinkdatabase(dbname)

4、转移数据库给新用户以已存在用户权限
exec sp_change_users_login 'update_one','newname','oldname'
go

5、检查备份集
RESTORE VERIFYONLY from disk='E:\dvbbs.bak'

6、修复数据库
Alter DATABASE [dvbbs] SET SINGLE_USER
GO
DBCC CHECKDB('dvbbs',repair_allow_data_loss) WITH TABLOCK
GO
Alter DATABASE [dvbbs] SET MULTI_USER
GO

7、日志清除
SET NOCOUNT ON
DECLARE @LogicalFileName sysname,
         @MaxMinutes INT,
         @NewSize INT


USE     tablename             -- 要操作的数据库名
Select   @LogicalFileName = 'tablename_log',   -- 日志文件名
@MaxMinutes = 10,               -- Limit on time allowed to wrap log.
         @NewSize = 1                   -- 你想设定的日志文件的大小(M)

-- Setup / initialize
DECLARE @OriginalSize int
Select @OriginalSize = size
   FROM sysfiles
   Where name = @LogicalFileName
Select 'Original Size of ' + db_name() + ' LOG is ' +
         CONVERT(VARCHAR(30),@OriginalSize) + ' 8K pages or ' +
         CONVERT(VARCHAR(30),(@OriginalSize*8/1024)) + 'MB'
   FROM sysfiles
   Where name = @LogicalFileName
Create TABLE DummyTrans
   (DummyColumn char (8000) not null)


DECLARE @Counter   INT,
         @StartTime DATETIME,
         @TruncLog   VARCHAR(255)
Select   @StartTime = GETDATE(),
         @TruncLog = 'BACKUP LOG ' + db_name() + ' WITH TRUNCATE_ONLY'

DBCC SHRINKFILE (@LogicalFileName, @NewSize)
EXEC (@TruncLog)
-- Wrap the log if necessary.
WHILE     @MaxMinutes > DATEDIFF (mi, @StartTime, GETDATE()) -- time has not expired
       AND @OriginalSize = (Select size FROM sysfiles Where name = @LogicalFileName)
       AND (@OriginalSize * 8 /1024) > @NewSize
   BEGIN -- Outer loop.
     Select @Counter = 0
     WHILE   ((@Counter < @OriginalSize / 16) AND (@Counter < 50000))
       BEGIN -- update
         Insert DummyTrans VALUES ('Fill Log')
         Delete DummyTrans
         Select @Counter = @Counter + 1
       END
     EXEC (@TruncLog)
   END
Select 'Final Size of ' + db_name() + ' LOG is ' +
         CONVERT(VARCHAR(30),size) + ' 8K pages or ' +
         CONVERT(VARCHAR(30),(size*8/1024)) + 'MB'
   FROM sysfiles
   Where name = @LogicalFileName
Drop TABLE DummyTrans
SET NOCOUNT OFF

8、说明：更改某个表
exec sp_changeobjectowner 'tablename','dbo'

9、存储更改全部表

Create PROCEDURE dbo.User_ChangeObjectOwnerBatch
@OldOwner as NVARCHAR(128),
@NewOwner as NVARCHAR(128)
AS

DECLARE @Name   as NVARCHAR(128)
DECLARE @Owner   as NVARCHAR(128)
DECLARE @OwnerName   as NVARCHAR(128)

DECLARE curObject CURSOR FOR
select 'Name'   = name,
   'Owner'   = user_name(uid)
from sysobjects
where user_name(uid)=@OldOwner
order by name

OPEN   curObject
FETCH NEXT FROM curObject INTO @Name, @Owner
WHILE(@@FETCH_STATUS=0)
BEGIN
if @Owner=@OldOwner
begin
   set @OwnerName = @OldOwner + '.' + rtrim(@Name)
   exec sp_changeobjectowner @OwnerName, @NewOwner
end
-- select @name,@NewOwner,@OldOwner

FETCH NEXT FROM curObject INTO @Name, @Owner
END

close curObject
deallocate curObject
GO


10、SQL SERVER中直接循环写入数据
declare @i int
set @i=1
while @i<30
begin
   insert into test (userid) values(@i)
   set @i=@i+1
end  

Tags: sql

'==================================================
'注册表操作声明
Public Declare Function RegOpenKey Lib "advapi32.dll" Alias "RegOpenKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Public Declare Function RegEnumValue Lib "advapi32.dll" Alias "RegEnumValueA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpValueName As String, lpcbValueName As Long, ByVal lpReserved As Long, lpType As Long, lpData As Byte, lpcbData As Long) As Long
Public Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
Public Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Public Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Public Declare Function RegEnumKeyEx Lib "advapi32.dll" Alias "RegEnumKeyExA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpName As String, lpcbName As Long, ByVal lpReserved As Long, ByVal lpClass As String, lpcbClass As Long, lpftLastWriteTime As Any) As Long
Public Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long
Public Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) As Long
Public Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hKey As Long, ByVal lpSubKey As String) As Long

Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_USERS = &H80000003
Private Const REG_SZ = 1&
Private Const REG_EXPAND_SZ = 2&
Private Const REG_BINARY = 3&
Private Const REG_DWORD = 4&
Private Const ERROR_SUCCESS = 0&
'==================================================


'================================
'注册表操作函数
'================================


'读取注册表字符串键值
Public Function GetString(hKey As Long, strPath As String, strValue As String)
Dim keyhand As Long
Dim lResult As Long
Dim strBuf As String
Dim lDataBufSize As Long
Dim intZeroPos As Integer
Dim lValueType As Long 'new add
RegOpenKey hKey, strPath, keyhand
lResult = RegQueryValueEx(keyhand, strValue, 0&, lValueType, ByVal 0&, lDataBufSize)
If lValueType = REG_SZ or lValueType = REG_EXPAND_SZ Then
strBuf = String(lDataBufSize, " ")
lResult = RegQueryValueEx(keyhand, strValue, 0&, lValueType, ByVal strBuf, lDataBufSize)
If lResult = ERROR_SUCCESS Then
intZeroPos = InStr(strBuf, Chr$(0))
If intZeroPos > 0 Then
GetString = left$(strBuf, intZeroPos - 1)
Else: GetString = strBuf
End If
End If
End If
End Function

'写入注册表字符串键值
Public Sub SetString(hKey As Long, strPath As String, strValue As String, strdata As String)
Dim keyhand As Long
RegCreateKey hKey, strPath, keyhand
RegSetValueEx keyhand, strValue, 0, REG_SZ, ByVal strdata, Len(strdata)
RegCloseKey keyhand
End Sub

'读取注册表 DWORD 键值
Function GetDword(ByVal hKey As Long, ByVal strPath As String, ByVal strValueName As String) As Long
Dim lResult As Long
Dim lValueType As Long
Dim lBuf As Long
Dim lDataBufSize As Long
Dim r As Long
Dim keyhand As Long

r = RegOpenKey(hKey, strPath, keyhand)

' Get length/data type
lDataBufSize = 4

lResult = RegQueryValueEx(keyhand, strValueName, 0&, lValueType, lBuf, lDataBufSize)

If lResult = ERROR_SUCCESS Then
If lValueType = REG_DWORD Then
GetDword = lBuf
End If
'Else
' Call errlog("GetDWORD-" & strPath, False)
End If

r = RegCloseKey(keyhand)
End Function

'写入注册表 DWORD 键值
Function SetDword(ByVal hKey As Long, ByVal strPath As String, ByVal strValueName As String, ByVal lData As Long)
Dim keyhand As Long
RegCreateKey hKey, strPath, keyhand
RegSetValueEx keyhand, strValueName, 0&, REG_DWORD, lData, 4
RegCloseKey keyhand
End Function

'读取注册表二进制键值
Function GetBinary(ByVal hKey As Long, ByVal strPath As String, ByVal strValueName As String) As Long
Dim lResult As Long
Dim lValueType As Long
Dim lBuf As Long
Dim lDataBufSize As Long
Dim r As Long
Dim keyhand As Long

r = RegOpenKey(hKey, strPath, keyhand)

' Get length/data type
lDataBufSize = 4

lResult = RegQueryValueEx(keyhand, strValueName, 0&, lValueType, lBuf, lDataBufSize)

If lResult = ERROR_SUCCESS Then
If lValueType = REG_BINARY Then
GetBinary = lBuf
End If
End If

r = RegCloseKey(keyhand)
End Function

'写入注册表二进制键值
Function SetBinary(ByVal hKey As Long, ByVal strPath As String, ByVal strValueName As String, ByVal lData As Long, ByVal BitNumber As Long)
Dim keyhand As Long
RegCreateKey hKey, strPath, keyhand
RegSetValueEx keyhand, strValueName, 0&, REG_BINARY, lData, BitNumber
RegCloseKey keyhand
End Function

'删除一个注册表键值
Public Function DeleteValue(ByVal hKey As Long, ByVal strPath As String, ByVal strValue As String)
Dim keyhand As Long
RegOpenKey hKey, strPath, keyhand
RegDeleteValue keyhand, strValue
RegCloseKey keyhand
End Function

'创建一个主键
Public Function CreateKey(ByVal hKey As Long, ByVal strKey As String)
Dim keyhand&
RegCreateKey hKey, strKey, keyhand
RegCloseKey keyhand&
End Function

Tags: vb

Tags: vb

动态创建菜单，鼠标右键弹出菜单，执行对应鼠标事件
'窗体
Option Explicit
Private Sub Form_Load()
hMenu = CreateMenu()
hmenupopup = CreatePopupMenu()
result = AppendMenu(hmenupopup, MF_STRING, 300, "新建")
result = AppendMenu(hmenupopup, MF_STRING, 301, "保存")
result = AppendMenu(hmenupopup, MF_STRING, 302, "另存为")
result = AppendMenu(hMenu, MF_POPUP, hmenupopup, "文件")
oldwinproc = GetWindowLong(Me.hWnd, GWL_WNDPROC)
SetWindowLong Me.hWnd, GWL_WNDPROC, AddressOf OnMenu
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
Dim r As RECT
Dim p As POINTAPI
If Button = vbRightButton Then
GetCursorPos p
TrackPopupMenu hmenupopup, 0, p.x, p.y, 0, Me.hWnd, r
End If
End Sub

Private Sub Form_Unload(Cancel As Integer)
SetWindowLong Me.hWnd, GWL_WNDPROC, oldwinproc
End Sub
'模块
Option Explicit

Public Declare Function CreateMenu Lib "user32" () As Long
Public Declare Function AppendMenu Lib "user32" Alias "AppendMenuA" (ByVal hMenu As Long, ByVal wFlags As Long, ByVal wIDNewItem As Long, ByVal lpNewItem As Any) As Long
Public Declare Function TrackPopupMenu Lib "user32" (ByVal hMenu As Long, ByVal wFlags As Long, ByVal x As Long, ByVal y As Long, ByVal nReserved As Long, ByVal hWnd As Long, lprc As RECT) As Long
Public Declare Function CreatePopupMenu Lib "user32" () As Long
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Public Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Public Const MF_STRING = &H0&
Public Const MF_POPUP = &H10&
Public Const WM_USER = &H400
Public Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type
Public Type POINTAPI
x As Long
y As Long
End Type
Public Const GWL_WNDPROC = (-4)
Public hMenu As Long
Public hmenupopup As Long
Public result As Long
Public oldwinproc As Long
Public Const WM_COMMAND = &H111

Public Function OnMenu(ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Select Case wMsg
Case WM_COMMAND
Select Case wParam
Case 300
MsgBox "u select new", vbInformation, "hello, world!"
Case 301
MsgBox "u select save", vbInformation, "hello, world!"
Case 302
MsgBox "u select save as", vbInformation, "hello, world!"
End Select
End Select
OnMenu = CallWindowProc(oldwinproc, hWnd, wMsg, wParam, lParam)
End Function

Tags: vb

'以下代码写在标准模块中
  Private FormOldWidth     As Long         '保存窗体的原始宽度
  Private FormOldHeight     As Long       '保存窗体的原始高度
   
  '在调用ResizeForm前先调用本函数
  Public Sub ResizeInit(FormName As Form)
      Dim Obj     As Control
      FormOldWidth = FormName.ScaleWidth    '记录窗体的原始宽度
      FormOldHeight = FormName.ScaleHeight    '记录窗体的原始高度
      On Error Resume Next
      For Each Obj In FormName
          Obj.Tag = Obj.Left & "   " & Obj.Top & "   " & Obj.Width & "   " & Obj.Height & "   "
      Next Obj
      On Error GoTo 0
  End Sub
   
  '按比例改变表单内各元件的大小，
  '在调用ReSizeForm前先调用ReSizeInit函数
  Public Sub ResizeForm(FormName As Form)
      Dim Pos(4)     As Double
      Dim i     As Long, TempPos       As Long, StartPos       As Long
      Dim Obj     As Control
      Dim ScaleX     As Double, ScaleY       As Double
      '在调试时如果出现除数为零错误，是因为没有设定form的初值，请双击form1然后再测试，这个问题绝对不会在编译好的程序中出现
      If FormOldWidth = 0 Then           '防止该错误的产生
          Exit Sub
      End If
      ScaleX = FormName.ScaleWidth / FormOldWidth               '保存窗体宽度缩放比例
      ScaleY = FormName.ScaleHeight / FormOldHeight           '保存窗体高度缩放比例
      On Error Resume Next
      For Each Obj In FormName
          StartPos = 1
      For i = 0 To 4
          '读取控件的原始位置与大小
          TempPos = InStr(StartPos, Obj.Tag, "   ", vbTextCompare)
          If TempPos > 0 Then
              Pos(i) = Mid(Obj.Tag, StartPos, TempPos - StartPos)
              StartPos = TempPos + 1
          Else
              Pos(i) = 0
          End If
          '根据控件的原始位置及窗体改变大小
          '按比例对控件重新定位与改变大小
          Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, Pos(2) * ScaleX, Pos(3) * ScaleY
      Next i
      Next Obj
      On Error GoTo 0
  End Sub
   
   
  Private Sub Form_Resize()
          ResizeForm Me
  End Sub

Private Sub Form_Load()
ResizeInit Me
End Sub

Tags: vb